編程思路破譯
N1賦值:6
N2賦值:12
N3賦值:24
RSV賦值:(收盤價-9日內最低價的最低值)/(9日內最高價的最高值-9日內最低價的最低值)*100
輸出K:RSV的3日[1日權重]移動平均,線寬為2,畫白色
輸出D:K的3日[1日權重]移動平均,線寬為2,畫黃色
輸出J:3*K-2*D,線寬為2,畫紅色
輸出DIFF:收盤價的12日指數移動平均-收盤價的26日指數移動平均,線寬為2,畫綠色
輸出DEA :DIFF的9日指數移動平均,線寬為2,畫藍色
輸出平滑異同平均:2*(DIFF-DEA),線寬為2,畫紅色
RSV1賦值:(9.8日內最高價的最高值-收盤價)/(9.8日內最高價的最高值-9.8日內最低價的最低值)*101
KK賦值:RSV1的3日[1日權重]移動平均
DD賦值:KK的3日[1日權重]移動平均
JJ賦值:3*KK-2*DD
買賣賦值:如果JJ>=100,返回100,否則返回如果JJ<=0,返回0,否則返回JJ
輸出明天買:如果買賣=100,返回0-10,否則返回0,COLOR00CCCC
輸出明天賣:如果買賣=0,返回90,否則返回100,COLOR00FF00
TYP賦值:(最高價+最低價+收盤價)/3
當滿足條件DIFF>1日前的DIFF時,在20和20位置之間畫柱狀線,寬度為2,0不為0則畫空心柱.,畫紅色
當滿足條件DIFF<1日前的DIFF時,在20和20位置之間畫柱狀線,寬度為2,0不為0則畫空心柱.,畫綠色
當滿足條件K>=1日前的KORK>DANDDIFF>1日前的DIFF時,在80和80位置之間畫柱狀線,寬度為2,1不為0則畫空心柱.,畫紅色
當滿足條件K<1日前的K時,在80和80位置之間畫柱狀線,寬度為2,1不為0則畫空心柱.,畫綠色
MACD金叉賦值:MACD上穿DIFF AND MACD>=(0-0.05) AND MACD<=0.02
當滿足條件MACD金叉時,在40位置書寫文字,畫紅色
XX賦值:最低價的3日簡單移動平均*0.96的30日指數移動平均
DIFF金叉賦值:如果DIFF上穿DEAANDXX-1日前的XX>0ANDMACD>=1日前的MACDANDDIFF<=0,返回1,否則返回0
當滿足條件DIFF金叉=1時,在35位置書寫文字,畫紅色
低位金叉賦值:DIFF上穿DEA AND DIFF<-0.1
當滿足條件低位金叉時,在25位置書寫文字,畫紅色
DIFDEA賦值:統計上次DEA>=0距今天數日中滿足DIFF上穿DEA的天數
二次金叉賦值:DIFF上穿DEA AND DEA<0 AND 統計21日中滿足DIFDEA=2的天數=1
當滿足條件二次金叉時,在20位置書寫文字,畫紅色
A1賦值:上次1日前的DIFF上穿DEA距今天數
MACD底背離賦值:A1+1日前的收盤價>收盤價 AND DIFF>A1+1日前的DIFF AND DIFF上穿DEA
當滿足條件MACD底背離時,在30位置書寫文字,畫紅色
A2賦值:上次1日前的DEA上穿DIFF距今天數
MACD頂背離賦值:A2+1日前的收盤價<收盤價 AND A2+1日前的DIFF>DIFF AND DEA上穿DIFF
當滿足條件MACD頂背離的5日過濾時,在100位置書寫文字
周DIFF賦值:'MACD.DIFF[取周線數據]'
周DEA賦值:'MACD.DEA[取周線數據]'
周MACD賦值:'MACD.MACD[取周線數據]'
DIF周金叉賦值:周DIFF上穿周DEA
當滿足條件DIF周金叉時,在45位置書寫文字,畫紅色
當滿足條件周DEA上穿周DIFF時,在110位置書寫文字
MACD周金叉賦值:周MACD上穿周DIFF AND 周MACD>=(0-0.05) AND 周MACD<=0.02
當滿足條件MACD周金叉時,在50位置書寫文字,畫紅色
月DIFF賦值:'MACD.DIFF[取月線數據]'
月DEA賦值:'MACD.DEA[取月線數據]'
月MACD賦值:'MACD.MACD[取月線數據]'
DIF月金叉賦值:月DIFF上穿月DEA
當滿足條件DIF月金叉時,在55位置書寫文字,畫紅色
當滿足條件月DEA上穿月DIFF時,在105位置書寫文字
MACD月金叉賦值:月MACD上穿月DIFF AND 月MACD>=(0-0.05) AND 月MACD<=0.02
當滿足條件MACD月金叉時,在60位置書寫文字,畫紅色
周K賦值:"KDJ的K[取周線數據]"(9,3,3)
周D賦值:"KDJ的D[取周線數據]"(9,3,3)
周J賦值:"KDJ的J[取周線數據]"(9,3,3)
月K賦值:"KDJ的K[取月線數據]"(9,3,3)
月D賦值:"KDJ的D[取月線數據]"(9,3,3)
月J賦值:"KDJ的J[取月線數據]"(9,3,3)
KD月金叉賦值:月K上穿月D
KD周金叉賦值:周K上穿周D
KD日金叉賦值:K上穿DANDD<50的4日過濾
KD低位金叉賦值:K上穿DANDD<20的4日過濾
當滿足條件KD月金叉時,在0位置書寫文字,畫紅色
當滿足條件KD周金叉時,在-5位置書寫文字,畫紅色
當滿足條件KD日金叉時,在-10位置書寫文字,畫紅色
當滿足條件KD低位金叉時,在5位置書寫文字,畫紅色
KD1賦值:統計上次D>=50距今天數日中滿足K上穿D的天數
KD二次金叉賦值:K上穿D AND D<50 AND 統計21日中滿足KD1=2的天數=1
當滿足條件KD二次金叉時,在10位置書寫文字,畫紅色
KD2賦值:統計上次D<=50距今天數日中滿足D上穿K的天數
KD二次死叉賦值:D上穿K AND D>50 AND 統計21日中滿足KD2=2的天數=1
當滿足條件KD二次死叉時,在95位置書寫文字
KD日死叉賦值:D上穿KANDD>80的4日過濾
當滿足條件KD日死叉時,在80位置書寫文字
當滿足條件周D上穿周K時,在85位置書寫文字
當滿足條件月D上穿月K時,在90位置書寫文字
KDB賦值:上次1日前的K上穿D距今天數
KDDB賦值:KDB+1日前的收盤價>收盤價 AND KDB+1日前的K<K AND K上穿D
KDJ底背離賦值:如果KDDB>0的5日過濾,返回1,否則返回0
當滿足條件KDJ底背離=1時,在15位置書寫文字,畫紅色
KDD賦值:上次1日前的D上穿K距今天數
KDJ頂背離賦值:KDD+1日前的收盤價<收盤價 AND KDD+1日前的K>K AND D上穿K
當滿足條件KDJ頂背離>0的5日過濾時,在120位置書寫文字
輸出RSI周金:當滿足條件"RSI的RSI1[取周線數據]"(N1,N2,N3)上穿"RSI的RSI2[取周線數據]"(N1,N2,N3)時,在65位置書寫文字,畫紅色
輸出RSI周死:當滿足條件"RSI的RSI2[取周線數據]"(N1,N2,N3)上穿"RSI的RSI1[取周線數據]"(N1,N2,N3)時,在130位置書寫文字
輸出RSI月金:當滿足條件"RSI的RSI1[取月線數據]"(N1,N2,N3)上穿"RSI的RSI2[取月線數據]"(N1,N2,N3)時,在70位置書寫文字,畫紅色
輸出RSI月死:當滿足條件"RSI的RSI2[取月線數據]"(N1,N2,N3)上穿"RSI的RSI1[取月線數據]"(N1,N2,N3)時,在115位置書寫文字
A3賦值:上次1日前的"RSI的RSI1"(6,12,24)上穿"RSI的RSI2"(6,12,24)距今天數
B3賦值:A3+1日前的收盤價>收盤價 AND A3+1日前的"RSI的RSI1"(6,12,24)<"RSI的RSI1"(6,12,24) AND "RSI的RSI1"(6,12,24)上穿"RSI的RSI2"(6,12,24)
RSI底背離賦值:B3>0的5日過濾
當滿足條件RSI底背離時,在75位置書寫文字,畫紅色
C3賦值:上次1日前的"RSI的RSI2"(6,12,24)上穿"RSI的RSI1"(6,12,24)距今天數
D3賦值:C3+1日前的收盤價<收盤價 AND C3+1日前的"RSI的RSI1"(6,12,24)>"RSI的RSI1"(6,12,24) AND "RSI的RSI2"(6,12,24)上穿"RSI的RSI1"(6,12,24)
RSI頂背離賦值:D3>0的5日過濾
當滿足條件RSI頂背離時,在125位置書寫文字
AZ賦值:現價
AC1賦值:1日前的收盤價
ZF1賦值:(AZ-AC1)/AC1*100
BZ賦值:總量
BV1賦值:1日前的成交量(手)
ZF2賦值:BZ/BV1*100
DZ賦值:1日前的收盤價-1日前的開盤價
EZ賦值:外盤-內盤
FZ賦值:1日前的成交量(手)-2日前的成交量(手)
預漲賦值:ZF1>1 AND ZF1<5 AND ZF2>30 AND DZ>0 AND EZ>0 AND FZ>0 AND D>1日前的D
當滿足條件預漲時,在D*0.6位置書寫文字,COLOR00CC00
KX賦值:250
KH賦值:KX日內K的最高值
DH賦值:KX日內D的最高值
JH賦值:KX日內J的最高值
KL賦值:KX日內K的最低值
DL賦值:KX日內D的最低值
JL賦值:KX日內J的最低值
HKMAX賦值:KH和DH和JH的較大值的較大值
LKMIN賦值:KL和DL和JL的較小值的較小值
KHLB賦值:(HKMAX+LKMIN)/2
KHLC賦值:HKMAX-LKMIN
MHF賦值:KX日內DIFF的最高值
MHD賦值:KX日內DEA的最高值
MHM賦值:KX日內MACD的最高值
MLF賦值:KX日內DIFF的最低值
MLD賦值:KX日內DEA的最低值
MLM賦值:KX日內MACD的最低值
HMAX賦值:MHF和MHD和MHM的較大值的較大值
LMIN賦值:MLF和MLD和MLM的較小值的較小值
FHLB賦值:(HMAX-LMIN)/100
FHLC賦值:HMAX-LMIN
SH賦值:(0-FHLB)*(KHLC/FHLC)+KHLB
DIFFA賦值:(DIFF-FHLB)*(KHLC/FHLC)+KHLB
DEAA賦值:(DEA-FHLB)*(KHLC/FHLC)+KHLB
MACDA賦值:(MACD-FHLB)*(KHLC/FHLC)+KHLB
MD1賦值:收盤價的80日簡單移動平均-收盤價的13日簡單移動平均/3
MD2賦值:(收盤價-MD1)/MD1的3日簡單移動平均
買點1賦值:MD2上穿0 AND 最低價/1日前的最高價<1.012 AND J<75 AND J>1日前的J
MA12賦值:收盤價的12日簡單移動平均
佳點賦值:如果MACD>=5日前的MACDANDOPEN<=1日前的收盤價ANDXX-1日前的XX>0ANDMACD<=0ANDMA12-1日前的MA12>=0的3日過濾ANDJ<80ANDJ>1日前的JANDD>1日前的DAND(DIFF>=1日前的DIFFORDEA>=R,返回F(DEA,1)),否則返回1
當滿足條件佳點=1時,在MACDA*0.98位置書寫文字,COLOR00CC00
DX0賦值:收盤價的2日指數移動平均-開盤價的5日指數移動平均
DX1賦值:如果DX0上穿MACDANDLOW<=XXANDMACD<=(0-0.11)AND(J<20ORK<20),返回1,否則返回0
當滿足條件DX1的3日過濾時,在0位置書寫文字,COLOR00CC00
MA10賦值:收盤價的10日簡單移動平均
SS賦值:最高價的3日簡單移動平均*1.05的30日指數移動平均
LQS賦值:如果0.7*(DIFF上穿DEAANDCLOSE<SSANDXX-1日前的XX>0ANDCROSS(MACD,0)ANDMACD>=0ANDDIFF>0ANDMA10-1日前的MA10>0ANDVOL>1日前的成交量(手))>=0.7AND(收盤價<SSANDXX-?日前的XX的?日過濾,返回)>0),5)ANDJ<80,否則返回1
當滿足條件LQS=1時,在MACDA*0.98位置書寫文字,COLOR00CC00
最佳點賦值:如果統計3日中滿足MD2>1日前的MD2的天數=3ANDCOUNT(MD2<0,10)=10ANDREF(MD2,3)=10日內MD2的最低值ANDJ<80ANDJ>1日前的J,返回1,否則返回0
買點2賦值:2日前的MD2=20日內MD2的最低值 AND 2日前的MD2<0.071 AND 2日前的MD2<1日前的MD2 ANDNOT(1日前的最低價>2日前的最高價 AND 最低價>1日前的最高價) AND 收盤價>1日前的收盤價 AND J<75 AND J>1日前的J
當滿足條件買點1OR買點2時,在D-1位置書寫文字,COLOR00CC00
程序源碼
N1:=6;N2:=12;N3:=24;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV,3,1),LINETHICK2,COLORWHITE;
D:SMA(K,3,1),LINETHICK2,COLORYELLOW;
J:3*K-2*D,LINETHICK2,COLORRED;
DIFF:EMA(CLOSE,12)-EMA(CLOSE,26),LINETHICK2,COLORGREEN;
DEA :EMA(DIFF,9),LINETHICK2,COLORBLUE;
MACD:2*(DIFF-DEA),LINETHICK2,COLORRED;
RSV1:=(HHV(H,9.8)-C)/(HHV(H,9.8)-LLV(L,9.8))*101;
KK:=SMA(RSV1,3,1);
DD:=SMA(KK,3,1);
JJ:=3*KK-2*DD;
買賣:=IF(JJ>=100,100,IF(JJ<=0,0,JJ));
明天買:IF(買賣=100,0-10,0),COLOR00CCCC;
明天賣:IF(買賣=0,90,100),COLOR00FF00;
TYP:=(HIGH+LOW+CLOSE)/3;
STICKLINE(DIFF>REF(DIFF,1),20,20,2,0),COLORRED;
STICKLINE(DIFF<REF(DIFF,1),20,20,2,0),COLORGREEN;
STICKLINE(K>=REF(K,1) OR K>D AND DIFF>REF(DIFF,1),80,80,2,1),COLORRED;
STICKLINE(K<REF(K,1),80,80,2,1),COLORGREEN;
MACD金叉:=CROSS(MACD,DIFF) AND MACD>=(0-0.05) AND MACD<=0.02;
DRAWTEXT(MACD金叉,40,'▲MACD金叉'),COLORRED;
XX:=EMA(MA(LOW,3)*0.96,30);
DIFF金叉:=IF(CROSS(DIFF,DEA) AND XX-REF(XX,1)>0 AND MACD>=REF(MACD,1) AND DIFF<=0,1,0);
DRAWTEXT(DIFF金叉=1,35,'▲DIFF金叉'),COLORRED;
低位金叉:=CROSS(DIFF,DEA) AND DIFF<-0.1;
DRAWTEXT(低位金叉,25,'▲低位金叉'),COLORRED;
DIFDEA:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));
二次金叉:=CROSS(DIFF,DEA) AND DEA<0 AND COUNT(DIFDEA=2,21)=1;
DRAWTEXT(二次金叉,20,'▲二次金叉'),COLORRED;
A1:=BARSLAST(REF(CROSS(DIFF,DEA),1));
MACD底背離:=REF(CLOSE,A1+1)>CLOSE AND DIFF>REF(DIFF,A1+1) AND CROSS(DIFF,DEA);
DRAWTEXT(MACD底背離,30,'▲MACD底背離'),COLORRED;
A2:=BARSLAST(REF(CROSS(DEA,DIFF),1));
MACD頂背離:=REF(CLOSE,A2+1)<CLOSE AND REF(DIFF,A2+1)>DIFF AND CROSS(DEA,DIFF);
DRAWTEXT(FILTER(MACD頂背離,5),100,'MACD頂背離') ;
周DIFF:='MACD.DIFF#WEEK';
周DEA:='MACD.DEA#WEEK';
周MACD:='MACD.MACD#WEEK';
DIF周金叉:=CROSS(周DIFF,周DEA);
DRAWTEXT(DIF周金叉,45,'▲DIFF周金叉'),COLORRED;
DRAWTEXT(CROSS(周DEA,周DIFF),110,'DIFF周死叉') ;
MACD周金叉:=CROSS(周MACD,周DIFF) AND 周MACD>=(0-0.05) AND 周MACD<=0.02;
DRAWTEXT(MACD周金叉,50,'▲MACD周金叉'),COLORRED;
月DIFF:='MACD.DIFF#MONTH';
月DEA:='MACD.DEA#MONTH';
月MACD:='MACD.MACD#MONTH';
DIF月金叉:=CROSS(月DIFF,月DEA);
DRAWTEXT(DIF月金叉,55,'▲DIFF月金叉'),COLORRED ;
DRAWTEXT(CROSS(月DEA,月DIFF),105,'DIFF月死叉') ;
MACD月金叉:=CROSS(月MACD,月DIFF) AND 月MACD>=(0-0.05) AND 月MACD<=0.02;
DRAWTEXT(MACD月金叉,60,'▲MACD月金叉'),COLORRED;
周K:="KDJ.K#WEEK"(9,3,3);
周D:="KDJ.D#WEEK"(9,3,3);
周J:="KDJ.J#WEEK"(9,3,3);
月K:="KDJ.K#MONTH"(9,3,3);
月D:="KDJ.D#MONTH"(9,3,3);
月J:="KDJ.J#MONTH"(9,3,3);
KD月金叉:=CROSS(月K,月D);
KD周金叉:=CROSS(周K,周D);
KD日金叉:=FILTER(CROSS(K,D) AND D<50,4);
KD低位金叉:=FILTER(CROSS(K,D) AND D<20,4);
DRAWTEXT(KD月金叉,0,'▲KD月金叉'),COLORRED;
DRAWTEXT(KD周金叉,-5,'▲KD周金叉'),COLORRED ;
DRAWTEXT(KD日金叉,-10,'▲KD日金叉'),COLORRED ;
DRAWTEXT(KD低位金叉,5,'▲KD低位金叉'),COLORRED;
KD1:=COUNT(CROSS(K,D),BARSLAST(D>=50));
KD二次金叉:=CROSS(K,D) AND D<50 AND COUNT(KD1=2,21)=1;
DRAWTEXT(KD二次金叉,10,'▲KD二次金叉'),COLORRED ;
KD2:=COUNT(CROSS(D,K),BARSLAST(D<=50));
KD二次死叉:=CROSS(D,K) AND D>50 AND COUNT(KD2=2,21)=1;
DRAWTEXT(KD二次死叉,95,'KD二次死叉') ;
KD日死叉:=FILTER(CROSS(D,K) AND D>80,4);
DRAWTEXT(KD日死叉,80,'KD日死叉') ;
DRAWTEXT(CROSS(周D,周K),85,'KD周死叉') ;
DRAWTEXT(CROSS(月D,月K),90,'KD月死叉') ;
KDB:=BARSLAST(REF(CROSS(K,D),1));
KDDB:=REF(CLOSE,KDB+1)>CLOSE AND REF(K,KDB+1)<K AND CROSS(K,D);
KDJ底背離:=IF(FILTER(KDDB>0,5),1,0);
DRAWTEXT(KDJ底背離=1,15,'▲KDJ底背離'),COLORRED;
KDD:=BARSLAST(REF(CROSS(D,K),1));
KDJ頂背離:=REF(CLOSE,KDD+1)<CLOSE AND REF(K,KDD+1)>K AND CROSS(D,K);
DRAWTEXT(FILTER(KDJ頂背離>0,5),120,'KDJ頂背離') ;
RSI周金:DRAWTEXT(CROSS("RSI.RSI1#WEEK"(N1,N2,N3),"RSI.RSI2#WEEK"(N1,N2,N3)) ,65,'▲RSI周金'),COLORRED;
RSI周死:DRAWTEXT(CROSS("RSI.RSI2#WEEK"(N1,N2,N3),"RSI.RSI1#WEEK"(N1,N2,N3)) ,130,'RSI周死') ;
RSI月金:DRAWTEXT(CROSS("RSI.RSI1#MONTH"(N1,N2,N3),"RSI.RSI2#MONTH"(N1,N2,N3)) ,70,'▲RSI月金'),COLORRED;
RSI月死:DRAWTEXT(CROSS("RSI.RSI2#MONTH"(N1,N2,N3),"RSI.RSI1#MONTH"(N1,N2,N3)) ,115,'RSI月死') ;
A3:=BARSLAST(REF(CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24)),1));
B3:=REF(C,A3+1)>C AND REF("RSI.RSI1"(6,12,24),A3+1)<"RSI.RSI1"(6,12,24) AND CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24));
RSI底背離:=FILTER(B3>0,5);
DRAWTEXT(RSI底背離,75,'▲RSI底背離'),COLORRED;
C3:=BARSLAST(REF(CROSS("RSI.RSI2"(6,12,24),"RSI.RSI1"(6,12,24)),1));
D3:=REF(C,C3+1)<C AND REF("RSI.RSI1"(6,12,24),C3+1)>"RSI.RSI1"(6,12,24) AND CROSS("RSI.RSI2"(6,12,24),"RSI.RSI1"(6,12,24));
RSI頂背離:=FILTER(D3>0,5);
DRAWTEXT(RSI頂背離,125,'RSI頂背離') ;
{預漲}
AZ:=DYNAINFO(7);
AC1:=REF(C,1);
ZF1:=(AZ-AC1)/AC1*100;
BZ:=DYNAINFO(8);
BV1:=REF(VOL,1);
ZF2:=BZ/BV1*100;
DZ:=REF(CLOSE,1)-REF(OPEN,1);
EZ:=DYNAINFO(23)-DYNAINFO(22);
FZ:=REF(VOL,1)-REF(VOL,2);
預漲:=ZF1>1 AND ZF1<5 AND ZF2>30 AND DZ>0 AND EZ>0 AND FZ>0 AND D>REF(D,1);
DRAWTEXT(預漲,D*0.6,'預\N漲'),COLOR00CC00;
KX:=250;
KH:=HHV(K,KX);
DH:=HHV(D,KX);
JH:=HHV(J,KX);
KL:=LLV(K,KX);
DL:=LLV(D,KX);
JL:=LLV(J,KX);
HKMAX:=MAX(KH,MAX(DH,JH));
LKMIN:=MIN(KL,MIN(DL,JL));
KHLB:=(HKMAX+LKMIN)/2;
KHLC:=HKMAX-LKMIN;
MHF:=HHV(DIFF,KX);
MHD:=HHV(DEA,KX);
MHM:=HHV(MACD,KX);
MLF:=LLV(DIFF,KX);
MLD:=LLV(DEA,KX);
MLM:=LLV(MACD,KX);
HMAX:=MAX(MHF,MAX(MHD,MHM));
LMIN:=MIN(MLF,MIN(MLD,MLM));
FHLB:=(HMAX-LMIN)/100;
FHLC:=HMAX-LMIN;
SH:=(0-FHLB)*(KHLC/FHLC)+KHLB;
DIFFA:=(DIFF-FHLB)*(KHLC/FHLC)+KHLB;
DEAA:=(DEA-FHLB)*(KHLC/FHLC)+KHLB;
MACDA:=(MACD-FHLB)*(KHLC/FHLC)+KHLB;
MD1:=MA(CLOSE,80)-MA(CLOSE,13)/3;
MD2:=MA((CLOSE-MD1)/MD1,3);
買點1:=CROSS(MD2,0) AND LOW/REF(HIGH,1)<1.012 AND J<75 AND J>REF(J,1);
MA12:=MA(CLOSE,12);
佳點:=IF(FILTER(MACD>=REF(MACD,5) AND OPEN<=REF(CLOSE,1) AND XX-REF(XX,1)>0 AND MACD<=0 AND MA12-REF(MA12,1)>=0,3) AND J<80 AND J>REF(J,1) AND D>REF(D,1) AND (DIFF>=REF(DIFF,1) OR DEA>=REF(DEA,1)),1,0);
DRAWTEXT(佳點=1,MACDA*0.98,'佳點'),COLOR00CC00;
DX0:=EMA(CLOSE,2)-EMA(OPEN,5);
DX1:=IF(CROSS(DX0,MACD) AND LOW<=XX AND MACD<=(0-0.11) AND (J<20 OR K<20),1,0);
DRAWTEXT(FILTER(DX1,3),0,'短10%'),COLOR00CC00;{短線}
MA10:=MA(CLOSE,10); SS:=EMA(MA(HIGH,3)*1.05,30);
LQS:=IF(FILTER(0.7*(CROSS(DIFF,DEA) AND CLOSE<SS AND XX-REF(XX,1)>0 AND CROSS(MACD,0) AND MACD>=0 AND DIFF>0 AND MA10-REF(MA10,1)>0 AND VOL>REF(VOL,1))>=0.7 AND (CLOSE<SS AND XX-REF(XX,1)>0),5) AND J<80,1,0);
DRAWTEXT(LQS=1,MACDA*0.98,'量價齊上'),COLOR00CC00;{量價齊上}
最佳點:=IF(COUNT(MD2>REF(MD2,1),3)=3 AND COUNT(MD2<0,10)=10 AND REF(MD2,3)=LLV(MD2,10) AND J<80 AND J>REF(J,1),1,0);
DRAWTEXT(最佳點=1,J,'最佳點'),COLOR00CC00;
買點2:=REF(MD2,2)=LLV(MD2,20) AND REF(MD2,2)<0.071 AND REF(MD2,2)<REF(MD2,1) AND
NOT(REF(LOW,1)>REF(HIGH,2) AND LOW>REF(HIGH,1)) AND CLOSE>REF(CLOSE,1) AND J<75 AND J>REF(J,1);
DRAWTEXT(買點1 OR 買點2,D-1,'買'),COLOR00CC00;
注：
館內各種公式為學習編程而保存，實戰使用前一定要看其中是否有未來函數并自己親自測試成功率，決不能依據公式名稱的描述和形容去投資，據此入市造成投資損失由投資者自己承擔。
發文不易，如獲益，歡迎贊賞，贊賞必復！
