選股公式運用。
簡單的選股指標公式(hjjdebug 整理）
基本教程：
----------------------------------------
1. 概念
收盤價：c,close
開盤價: o,open
最高價: h,high
最低價 l,low
成交量: v，volume
股本: capital(手數）
換手率: (vol/capital)
個股分時圖上都有一條黃線,叫做均價線： a/capital*100;
量比的含義： v/ref(v,1) // 當前成交量與前一天成交量之比
股價上漲：c>ref(c,1)
漲幅：(c-ref(c,1))/c*100;
----------------------------------------
2. 函數
n日內最高的x：hhv(x,n)
n日內最低的x：llv(x,n)
n日內平均線值: ma(x,n)
向前引用: ref(x,n)
A線，B線交叉: cross(A,B)
計算滿足條件的天數：count(cond,n)
求n日內的和：sum(value,n)
舉例:
10天換手率之和: sum(v/capital,10)
20天內漲停的天數: count((c/ref(c,1)>1.09, 20)
cross(c,ma(c,5)), 收盤價上穿5日均線
cross(ma(c,5),c)，5日均線下穿股價
----------------------------------------
甲: 當前形態(tài)
1. 收陰線
c<o
2. 收陽線
c>o
3. 上影線
c<h
4. 下影線
c>l
5. 下影線長于上影線
xg:(c-l)>(h-c);
6. 流通盤小于4000萬 的選股公式
xg:CAPITAL/100<4000;
7, K線收十字星
abs(c-o)/o<0.01;
8. 大福震蕩選股
xg:h/ref(c,1)>1.09 and ref(c,1)/l>1.09;
9. 大部分股票跌到43日均線時就會反彈，如果在43日均線附近買入，短線成功率占90%以上，即時選出還差幾分錢就跌到43日均線的股票。
xg:abs(c-ma(c,43))/ma(c,43)<0.01;
---------------------------------------
乙： 兩點判別 (今天與昨天， 今天與平均值等）
1，量比大于1.1 同時換手大于3,漲幅>7個點的公式
xg:v/ref(v,1)>1.1 and v/CAPITAL*100>3 and (c/ref(c,1) > 1.07)
2，"陰轉陽"的公式(也就是昨天收陰線,今天收陽線)
xg:ref(c,1)<ref(o,1) and c>o;
3，上穿30日均線的公式
xg:cross(c,ma(c,30));
4，前天和今天為陰線，并且兩筆陰線最低點相等
xg:ref(c,2)<ref(o,2) AND c<o AND ref(l,2)=l;
5，最低價小于昨天的最低價但收盤后為陽線。
xg:l<ref(l,1) and c>o;
6, 30日均線走平或走高的個股
xg:ma(c,30)>ref(ma(c,30),1);
7，選周線跳空缺口的個股。
周期選周線
xg:HIGH<REF(LOW,1) ;跳空
xg:LOW>REF(HIGH,1) ;跳高
8，前天到今天兩天內,累計下跌等于或超過20%選股.
xg:(ref(c,2)-c)/c>0.2;
----------------------------------------
丙：n 天以來的走勢（最高值，最低值，平均值等）
1. 30個交易日內,股價跌幅達到一半的股票
xg:(hhv(c,30)-c)/hhv(c,30)>0.5;
2，今天的量 是5天平均的 2倍以上
xg:v>ma(v,5)*2;
縮量
xg:vol/ma(vol,10)<0.3;
3，股價是25天以來新低.
xg:c<ref(llv(c,25),1);
4，股價回抽20日均線選股公式
xg:ref(c,1)>ma(c,20) and cross(ma(c,20),c);
5，一根大陽線,至少有5個點以上,再連著出現二根振幅不大于5的十字星或是小K 線
xg:(ref(c,3)-ref(c,4))/ref(c,3)>0.05 and count((h-l)/l<0.05,2)=2;
6，一陽上穿10，20，30日線，量能是前一天3倍。
xg:cross(c,ma(c,10)) and cross(c,ma(c,20)) and cross(c,ma(c,30)) and v>ref(v,1)*3;
7，三線包容
共三根K線，
第一根K線為陰線；
第二根K線為陰線，最高價低于第一根K線 ，最低價高于第一根K線；
第三根K線陰陽不限，最高價低于第二根K線，最低價高于第二根K線。滿足后發(fā)出信號
w1:=ref(c,2)<ref(o,2);
w2:=ref(c,1)<ref(o,1) and ref(h,2)>ref(h,1) and ref(l,2)<ref(l,1);
w3:=ref(h,1)>h and ref(l,1)<l;
xg:w1 and w2 and w3;
8，選出10天內出現了漲停的個股
xg:count(c/ref(c,1)>1.09,10)>0;
9， 連續(xù)5天，當日的5日均線減前一天的5日均線差值小于1.
xg:count((ma(c,5)-ref(ma(c,5),1))<1,5)=5;
10，5日均線向上 流通盤小于5000萬 換手率大于3的選股公式
var1:CAPITAL/100<5000;
var2:=VOL/CAPITAL>3%;
var3:ma(c,5)>ref(ma(c,5),1);
xg:var1 and var2 and var3;
11，30日內到本日收盤價下跌20%的公式
xg:hhv(c,30)/c>1.2;
12，連續(xù)4天的收盤價格波動幅度在3%之內連續(xù)走平或向上
xg:count(abs(c-ref(c,1)/ref(c,1))<0.03 and c>ref(c,1),3)=3;
13，換手率10天80%以上的選股公式
xg:sum(VOL/CAPITAL*100,10)>80;
14，60個交易日內，漲幅大于9.9%（漲停）的天數
count(c/ref(c,1)>1.099,60);
15，昨天跌幅大于3%，今天開盤高開2%以上的選股公式。
xg:ref(c,1)/ref(c,2)<0.97 and o/ref(c,1)>1.02;
16，選出周換手率小于10%的股票
sum(VOL/CAPITAL*100,5)<10;
17，成交量創(chuàng)20日新低，并且股價也創(chuàng)20日新低
xg:v=llv(v,20) and c=llv(c,20);
18，５日不漲,綠線收盤選票指標
count(c<o,5)=5;
----------------------------------------
使用指標公式
1，選股：ＥＸＰＭＡ ５日與１０日金叉 并且第二天的收盤價在ＥＸＰＭＡ的 ５日線以上．
cross(ref(ema(c,5),1),ref(ema(c,10),1)) and c>ema(c,5);
2，請編買入公式：
1. 將BIAS指標的參數設置為24日，將KD指標的參數設置為9；3；3。
2. BIAS指標要小于-6，這只是確認該股超跌的初選條件。
3. KD指標產生黃金交叉，K線上穿D線。
4. KD交叉同時，KD指標中的D值要小于16。
BIAS3 :=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100,colorff00ff;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1),COLORWHITE;
D:=SMA(K,3,1),COLORYELLOW;
xg:BIAS3<-6 and cross(k,d) and d<16;
3，kdj的J從上向下穿越O軸發(fā)出信號
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1),COLORWHITE;
D:=SMA(K,3,1),COLORYELLOW;
J:=3*K-2*D,COLORFF00FF;
xg:cross(0,j);
4，"今日MACD等于昨天的MACD ,且macd>0" 的指標
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
xg:macd=ref(macd,1) and macd>0
----------------------------------------
1，連續(xù)２天收盤價跌破３０日均線，就顯示＂賣出＂信號
a1:count(c<ma(c,30),2)=2;
drawtext(a1,c,賣出),colorgreen;
2，股票在這條均線上在8天以上，上下幅度不大，
a1:abs((c-ma(c,120))/ma(c,120))<0.1;xg:count(a1,8)=8;
3， 連續(xù)三天高開高走的選股公式 // 要看他的歷史位置及幅度
count(o>ref(c,1) and c>o,3)=3;
4，n天內曾經有m個漲停
count(c/ref(c,1)>1.09,n)>m;
5，股價比昨天的高，量比昨天小。連續(xù) n 天, 價升量減
count(c>ref(c,1) and v<ref(v,1), n) = n
6，連續(xù)3天每天的最低價都比前一天高
count(l>ref(c,1),3)=3;
7，股價超過五日均價的15%以上，并給出賣出信號賣出:
c/ma(c,5)>1.15;
8，連收兩個十字星的選股公式
count(abs((c-o)/o<0.01),2)=2;
9，n橫盤天數，n1橫盤的上下幅度
REF(((HHV(H,N)-LLV(L,N))/LLV(L,N)),1)<=(n1/100)and ref(v,1)<ref(ma(v,5),1) and cross(v,ma(v,5)) and cross(v,ma(v,10));
10，收盤價連續(xù)8天都站在5日均線的股票。
count(c>ma(c,5),8)=8;
11，振幅大于5%，收盤價大于3.5小于15元，三日均線大于昨日的三日均線。
a1:=h/l>1.05;
a2:=c>3.5 and c<15;
a3:=ma(c,3)>ref(ma(c,3),1);
xg:a1 and a2 and a3;
12,收盤價下有60天前的遠期獲利盤n%。
aa:WINNER(ref(c,60 ))*100;
13，連續(xù)三日收陽 后日收盤高于前日 且每日收于當日最高價附近 每日漲幅不大于4%選股:
count(c>o and c>ref(c,1) and abs((h-c)/c)<0.01 and c/ref(c,1)<1.04,3)=3;
14，股價突破5ma買入，跌破5ma賣出。買入和賣出用箭頭表示 （副圖）
a1:cross(c,ma(c,5));
a2:cross(ma(c,5),c);
drawtext(a1,low*0.98,↑),colorred;
drawtext(a2,h*1.02,↓),color00ffff;
15，歷史高點到前一高點畫線
POLYLINE(h>=hhv(c,0),h);
16，均線中增加一根線,這根線的價格是5日線的1.2倍
aa:ma(c,5)*1.2;
17，N天前換手率大于8%
REF(VOL/CAPITAL*100,N)>8;
18，一條均線18MA 股價上漲后“縮量”回調到18MA
XG:COUNT(V<REF(V,1) AND C<O,N)=N AND C>MA(C,18);
N “縮量”回調的天數
19，1。昨日量是n天以來最低量，（n可調）；2。今日量是昨日量的m倍，（m可 調）；3。今日k線收陽線；
xg:ref(v,1)=llv(ref(v,1),n) and v>ref(v,1)*m and c>o;
20，第一天收陰，第二天，第三天，第四天，收出紅三兵
XG:REF(C,3)<REF(C,4) AND COUNT(C>O,3)=3;
21，最近3天(包括昨天.前天)股價突破250日均線COUNT(C>MA(C,250),3)=3;
22，60與120均線距離在n%內
XG:ABS((MA(C,60)-MA(C,120))/MA(C,120))<N/100;
23，5日均線傾角大于60度
X:(ATAN((MA(C,5)/REF(MA(C,5),1)-1)*100)*180/3.14115926)>60
也可以這樣：
X:(ATAN((EMA(C,5)/REF(EMA(C,5),1)-1)*100)*180/3.14115926)>60;
25,K線沿著5日均線往上爬的選股公式
w1:=ma(c,5);
w2:=abc(c-w1)/w1<0.01;
xg:count(w1>ref(w1,1),5)=5 and w2;
26,平臺整理的公式,整理時間和整理幅度可調
(HHV(CLOSE,N)-LLV(CLOSE,N))/LLV(CLOSE,N)<=(N1/100);N整理時間,N1整理幅度
27,選出當日最低價在10日均線上下0.05%內，收盤價在均線上方的個股
abs(l-ma(c,10))<0.005 and c>ma(c,10);
28,第一天股票漲停，第二天成交量是第一天成交量的１倍,.那第三天就是買點
w1:=ref(c,2)/ref(c,3)>1.1;
w2:=ref(v,1)/ref(v,2)>2;
xg:w1 and w2;
29,3日均線上穿10日均線，KDJ有效金叉
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
w1:=cross(ma(c,3),ma(c,10));
xg:w1 and cross(k,d);
30,連續(xù)3-5天,每天的收盤價漲跌幅不超過1%.
w1:abs(c-o)<0.01;
xg:count(w1,5)>=3;
31,MACD在8天以內兩次金叉
DIFF:=(EMA(CLOSE,12) - EMA(CLOSE,26));
DEA:=EMA(DIFF,9),COLORBLUE,LINETHICK0;
MACD:=2*(DIFF-DEA);
w1:cross(DIFF,dea);
xg:count(w1,8)>=2;
32,于20日均線相差2個百分點的
w1:abs(c-ma(c,20)/ma(c,20)*100<2;
N日均線相差M個百分點的公式h
w1:abs(c-ma(c,n)/ma(c,n)*100<m; //n：N日 m：M個百分點
33, 股價回調到14日均線的選股 abs(c-ma(c,14))/ma(c,14)<0.005;
34,MACD的拐點公式
DIFF:=(EMA(CLOSE,12) - EMA(CLOSE,26));
DEA:=EMA(DIFF,9),COLORBLUE,LINETHICK0;
MACD:=2*(DIFF-DEA);
拐點:ref(macd,2)>ref(macd,1) and ref(macd,1)<macd;
35,跳空高開收陽線LOW>REF(HIGH,1) and c>o;
36,漲停過300日線的選股公式c/ref(c,1)>1.09 and cross(c,ma(c,300));
37，成交量是前5天中10天均量線中最小值的3.5倍以上
w1:=llv(ma(v,10),5);
xg:v>w1*3.5;
38，跳空高開后，三天內沒有回補缺口
ref(LOW,2)>REF(HIGH,3) and l>ref(LOW,2);
39， {5日內第二大量}
zdl:=hhv(v,5);
v0:=IF(v>=zdl,0,v);
v1:=IF(ref(v,1)>=zdl,0,ref(v,1));
v2:=IF(ref(v,2)>=zdl,0,ref(v,2));
v3:=IF(ref(v,3)>=zdl,0,ref(v,3));
v4:=IF(ref(v,4)>=zdl,0,ref(v,4));
第二大量:MAX(MAX(MAX(MAX(v0,v1),v2),v3),v4);
DRAWTEXTABS( 0,10 ,第一大量 + zdl+ 第二大量+第二大量);同理可求出第三大 、第四大和最小量.
實現簡單的排列.這個公式好比是一件完整產品中的一個零部件,解決了一個思路問題.
40，{5日均線傾角大于60度}
X:(ATAN((MA(C,5)/REF(MA(C,5),1)-1)*100)*180/3.14115926)>60;
累積能量線 OBV (On Balance Volume )
收集派發(fā)（Accumulation Distribution）
指數平均數（EXPMA）
MACD稱為指數平滑異動平均線(Moving Average Convergence and Divergence)
DIFF線 收盤價短期、長期指數平滑移動平均線間的差 DEA線 DIFF線的M日指數平滑移動平均線 MACD線 DIFF線與DEA線的差，彩色柱狀線 參數：SHORT(短期)、LONG(長期)、M 天數，一般為12、26、9
————————————————
版權聲明：本文為CSDN博主「hjjdebug」的原創(chuàng)文章，遵循CC 4.0 BY-SA版權協(xié)議，轉載請附上原文出處鏈接及本聲明。
原文鏈接：https://blog.csdn.net/hejinjing_tom_com/article/details/12218005
